D = 30;
d = 15;
t = 5;
lc = 5;
lc2=2; // raffinement en sortie
lc3=2; // raffinement en entree

/* premier grand cercle C1 */ 
Point(1) = {0, 0, 0, lc};
Point(2) = {D/2, 0, 0, lc};
Point(3) = {0, D/2, 0, lc};
Point(4) = {-D/2, 0, 0, lc};
Point(5) = {0, -D/2, 0, lc};

/* premier petit cercle c1 */ 
Point(6) = {0, 0, 5*D, lc3};
Point(7) = {d/2, 0, 5*D, lc3};
Point(8) = {0, d/2, 5*D, lc3};
Point(9) = {-d/2, 0, 5*D, lc3};
Point(10) = {0, -d/2, 5*D, lc3};

/*troisieme grand cercle C3*/ 
Point(11) = {0, 0, 5*D+t, lc2};
Point(12) = {D/2, 0, 5*D+t, lc2};
Point(13) = {0, D/2, 5*D+t, lc2};
Point(14) = {-D/2, 0, 5*D+t, lc2};
Point(15) = {0, -D/2, 5*D+t, lc2};

/* C1 */
Circle(1) = {2, 1, 5};
Circle(2) = {5, 1, 4};
Circle(3) = {4, 1, 3};
Circle(4) = {3, 1, 2};

/* c1 */
Circle(5) = {7, 6, 10};
Circle(6) = {10, 6, 9};
Circle(7) = {9, 6, 8};
Circle(8) = {8, 6, 7};

/* C3 */
Circle(9) = {12, 11, 15};
Circle(10) = {15, 11, 14};
Circle(11) = {14, 11, 13};
Circle(12) = {13, 11, 12};

/* Def surface C1 */
Line Loop(72) = {4, 1, 2, 3};
Plane Surface(73) = {72};

/* Def surface c1 */
Line Loop(74) = {5, 6, 7, 8};
Plane Surface(75) = {74};

/* Def surface C3 */
Line Loop(76) = {9, 10, 11, 12};
Plane Surface(77) = {76};

// Si on veut des carrés à la place de triangles pr mailler
Recombine Surface {73} ;
Recombine Surface {75} ;
Recombine Surface {77} ;

// Definition du maillage par couche : 2 layers 
// une de 0 a 0.8, l'autre de 0.8 a 1
// 50 subdivisions pour l'une, 100 pour l'autre
/*Extrusion C1 */
Extrude {0,0,5*D} { 
  Surface{73}; Layers{ {100,100}, {0.8,1} }; Recombine; 
}

/*Extrusion c1 */
Extrude {0,0,t} { 
  Surface{75}; Layers{ 40 }; Recombine; 
}

/*Extrusion C3 */
Extrude {0,0,10*D} { 
  Surface{77}; Layers{ {100,100}, {0.2,1}}; Recombine; 
}



