[Gmsh] Mesh with nodes at specific locations

[Christophe Geuzaine]

sss.larnier at libertysurf.fr wrote:
> Hello
>  
> I'm Ph.D student in applied mathematics in Toulouse (France). I'm a 
> beginner in the use of gmsh. I've got one question about meshes.
>  
> I've create a sphere and I would like a 3D mesh with nodes at specific 
> locations on the surface of the sphere. The question is : How can I do 
> that ?
>  
> My first idea is to create my sphere by using points for the arc 
> circle at the locations that interest me then take all the arc circles 
> in the surface, next the volume. Then I hope that when I launch the 
> mesh. It will use the specific locations for the nodes.
>  
> Will it work ? 

Yes, it should work.

> Tell me if you have an other way.
>  

You could use "embedded points":

lc = .5;
Point(1) = {0.0,0.0,0.0,lc};
Point(2) = {1,0.0,0.0,lc};
Point(3) = {0,1,0.0,lc};
Circle(1) = {2,1,3};
Point(4) = {-1,0,0.0,lc};
Point(5) = {0,-1,0.0,lc};
Circle(2) = {3,1,4};
Circle(3) = {4,1,5};
Circle(4) = {5,1,2};
Point(6) = {0,0,-1,lc};
Point(7) = {0,0,1,lc};
Circle(5) = {3,1,6};
Circle(6) = {6,1,5};
Circle(7) = {5,1,7};
Circle(8) = {7,1,3};
Circle(9) = {2,1,7};
Circle(10) = {7,1,4};
Circle(11) = {4,1,6};
Circle(12) = {6,1,2};
Line Loop(13) = {2,8,-10};
Ruled Surface(14) = {13};
Line Loop(15) = {10,3,7};
Ruled Surface(16) = {15};
Line Loop(17) = {-8,-9,1};
Ruled Surface(18) = {17};
Line Loop(19) = {-11,-2,5};
Ruled Surface(20) = {19};
Line Loop(21) = {-5,-12,-1};
Ruled Surface(22) = {21};
Line Loop(23) = {-3,11,6};
Ruled Surface(24) = {23};
Line Loop(25) = {-7,4,9};
Ruled Surface(26) = {25};
Line Loop(27) = {-4,12,-6};
Ruled Surface(28) = {27};
Surface Loop(29) = {28,26,16,14,20,24,22,18};
Volume(30) = {29};

// embed a couple of points in the surface mesh
Point(100) = {0.5,0.5,Sqrt(0.5), lc};
Point(101) = {0.6,0.6,Sqrt(0.28), lc};
Point{100,101} In Surface{18};





> Greetings
>  
> Stanislas LARNIER
> 
> 
> ------------------------------------------------------------------------
> 
> _______________________________________________
> gmsh mailing list
> gmsh at geuz.org
> http://www.geuz.org/mailman/listinfo/gmsh


-- 
Prof. Christophe Geuzaine
University of Liege, Electrical Engineering and Computer Science
http://www.montefiore.ulg.ac.be/~geuzaine